How to update AMP to the latest version

IceOfWraith · 25 October 2022 02:32

1. Overview

AMP has several components that are updated independently:

Component	Description
AMP instance manager	This is the command line tool used to configure instances
AMP instances	These include ADS (the main instance, which manages other instances) and the instances that run applications like game servers
Generic Module instance configurations	Instances created using the Generic Module have a “template” configuration that tells the Generic Module how to configure the instance. Most instance types in AMP use the Generic Module

Each component and the method for updating it is discussed below.

Note this article focuses on updating AMP’s components. The game server or other application that is managed by an AMP instance is also updated separately - by managing the instance and clicking “Update” on the Metrics and Status page.

2. Updating the instance manager

2.1 Linux

Important Note

If after following the below instructions, ampinstmgr is not being updated, it may be due to an outdated or disabled CubeCoders repo on your system.

On more recent versions of AMP run:
sudo su -l
getamp addRepo

On older versions run:
sudo su -l
bash <(wget -qO- getamp.sh) addRepo

Then retry the relevant commands below.

On more recent versions of AMP you can handle updating both the AMP instance manager (ampinstmgr) and AMP instances by running the following commands:

sudo su -l
getamp update

On Linux older installs you’ll need to update the AMP instance manager (ampinstmgr) via your distribution’s package manager:

Ubuntu/Debian/deb-based

sudo apt update
sudo apt upgrade

This will update all packages on your system. If you want to only update AMP then replace the second command with:

sudo apt upgrade ampinstmgr

CentOS/Fedora/Red Hat/rpm-based

sudo yum update

This will update all packages on your system. If you want to only update AMP then run:

sudo yum update ampinstmgr

2.2 Windows

See section 5 below for a sample batch script for automating the below process, as well as the upgrade of ADS in section 3.

Make sure all instances are fully stopped. You can do this by running ampinstmgr stopall in the command prompt.
Verify no AMP process are running in Task Manager and end them if so.
Download a fresh copy of the installer and run the installation again, selecting the option appropriate to your situation.
Due to issues with upgrades on Windows, it’s best to run the AMPSetup.msi installer a second time choosing the repair option to ensure all items are upgraded fully.

3. Updating your AMP instances

Windows and Linux

ADS can manage instances that are of a similar version, where all parts of the version number are the same except the last. For example ADS version 1.9.6.2 could manage an instance of version 1.9.6.0 or 1.9.6.4, but not of 1.9.7.0.

When you do upgrade instances, do so as the user running AMP (such as amp on Linux or AMP on Windows). On Linux, switch to the amp user by running sudo su -l amp.

You can then upgrade AMPs central management interface (ADS) by running:

ampinstmgr upgradeall

(On Windows Server only, this specific command needs to be run in an Administrator Command Prompt or Powershell Terminal. This is an exception to the general rule not to use the Administrator user with AMP.)

Once AMP is running again, you can use the “Update All” button to update each Generic Module game instance. Otherwise, AMP will update each Generic Module game instance when it is next started.

If you only want to update ADS, run:

ampinstmgr upgrade ADS

(On Windows Server only, this specific command needs to be run in an Administrator Command Prompt or Powershell Terminal. This is an exception to the general rule not to use the Administrator user with AMP.)

On Windows, it may be necessary to reboot the system after updating AMP.

See section 5 below for a sample batch script for automating the upgrade of ADS on Windows, as well as the process in section 2.2.

4. Updating Generic Module instance configurations

The “template” configurations for Generic Module instances can be updated in one of the following ways:

by clicking the update button on the instance tile:
or
by clicking the “Update All” button at the top of the instance list:
or
by starting the relevant instance(s) for the first time after running the upgrade command for that instance, or the upgradeall command, as per section 3 above.

Updating from the Support and Updates tab inside the instance, won’t update the Generic Module template configurations.

Generic Module templates can be changed at any time - they don’t need to wait for a new AMP release. So it is a good idea to keep your templates and Generic Module instances up to date.

In some cases after you update a Generic Module instance configuration, you will also need to update the application that the instance manages to get all the changes applied. This particularly affects Palworld, Arma Reforger, DayZ and The Isle, but can also affect servers like Arma 3, any Source or GoldSrc server, Veloren, Necesse and others. Manage the instance and click “Update” on the Status page to do this.

5. Update script for Windows

The below batch script is a community-provided (thanks @Greelan!) example script for automating the update process on Windows. To use it, save the script as a batch file (such as UpdateAMP.bat), and run it as the AMP user in a Command Prompt or Powershell Terminal:

@echo off
rem Script to update AMP Instance Manager and ADS
rem Save as a batch file (such as UpdateAMP.bat) and run as the AMP user in a Command Prompt or Powershell Terminal

echo.
echo Updating AMP...
echo All AMP processes will first be stopped
set /p answer=Continue? (Y/n): 
if /i "%answer%"=="n" (
    echo Aborting
    exit 0
)

ampinstmgr stopall
sc query "AMP-ADS01" | findstr /I "RUNNING" >nul
if %errorlevel%==0 (
    net stop "AMP-ADS01"
)

echo.
echo A new AMP installer will now be downloaded and run
echo ADS will then be updated
set /p answer=Continue? (Y/n): 
if /i "%answer%"=="n" (
    echo Restarting AMP and aborting
    ampinstmgr start ADS
    exit 0
)

echo.
echo Downloading...
powershell -Command "$ProgressPreference='SilentlyContinue'; wget -O AMPSetup.msi https://cdn-downloads.c7rs.com/AMP/Mainline/AMPSetup.msi"
echo Done

echo.
echo Running installer...
msiexec /i "AMPSetup.msi"

echo.
echo Updating ADS...
rem On Windows Server, ADS needs to be updated via an Administrator shell
for /f %%i in ('powershell -NoProfile -Command ^
  "((Get-CimInstance -ClassName Win32_OperatingSystem).ProductType)"') do set "ProductType=%%i"

if "%ProductType%"=="1" (
    ampinstmgr upgradeall
) else (
    powershell -Command "Start-Process 'ampinstmgr' -ArgumentList 'upgradeall' -Verb RunAs -Wait"
)

echo.
echo Starting ADS...
ampinstmgr start ADS

echo.
echo AMP Instance Manager and ADS have now been updated
echo Log in to AMP and click "Update All" to update all Generic module instances and their configurations
echo Otherwise each Generic module instance and its configuration will be updated when next started